Below are some of the death trap examples from TBA.
DEATHTRAPS
Rooms that will kill mortals on entry. All dropped items may be junked.
Since many people are not a fan of DT's I suggest a more painful and slow
near death trap:
Example: TSTAT 3008, 12000, 6100, 6300, 41004
See also: TRIGEDIT-MOB-DEATH, ROOMFLAGS, GROUP, SCORE
Code:
Name: 'Near Death Trap', VNum: [ 3008], RNum: [ 804]
Trigger Intended Assignment: Rooms
Trigger Type: Enter , Numeric Arg: 100, Arg list: None
Commands:
* By Rumble of The Builder Academy tbamud.com 9091
* Near Death Trap stuns actor
set stunned %actor.hitp%
%damage% %actor% %stunned%
%send% %actor% You are on the brink of life and death.
%send% %actor% The Gods must favor you this day.
Code:
Name: 'Near Death Trap Lions - 12017', VNum: [12000], RNum: [ 1554]
Trigger Intended Assignment: Rooms
Trigger Type: Enter , Numeric Arg: 100, Arg list: None
Commands:
* Near Death Trap stuns actor
wait 1 sec
set stunned %actor.hitp%
%damage% %actor% %stunned%
wait 5 sec
%send% %actor% The lions grow bored once you stop struggling and leave you to die.
Code:
Name: 'Near Death Trap Spiders - 6131', VNum: [ 6100], RNum: [ 975]
Trigger Intended Assignment: Rooms
Trigger Type: Enter , Numeric Arg: 100, Arg list: None
Commands:
* Near Death Trap stuns actor, then poison will almost kill them.
wait 3 sec
set stunned %actor.hitp%
%damage% %actor% %stunned%
wait 3 sec
dg_affect %actor% poison on 1
%send% %actor% The spiders wrap you up and leave you to die.
Code:
Name: 'Near Death Trap Mahatma - 6318', VNum: [ 6300], RNum: [ 978]
Trigger Intended Assignment: Mobiles
Trigger Type: Greet , Numeric Arg: 100, Arg list: None
Commands:
* By Rumble of The Builder Academy tbamud.com 9091
* Near Death Trap - Mahatma stuns actor and then takes all of their equipment.
wait 3 sec
say Here, have a quick trip to the Temple of Midgaard.
wait 2 sec
%send% %actor% Mahatma plunges a black dagger into your back and takes all your equipment.
%echoaround% %actor% Mahatma plunges a black dagger into %actor.name%'s back and takes all
of %actor.hisher% equipment.
* Damage the actor to 0 hitpoints so they lay there stunned, unable to move.
* They will recover.
set stunned %actor.hitp%
%damage% %actor% %stunned%
* steal all their inventory.
set i %actor.inventory%
while %i%
set pge 1
if %i.type% == container
if %i.contents%
set i %container.contents%
* Don't purge containers inside containers or mudmail.
if %i.type% == container || %i.vnum% <= 1
set pge 0
end
end
end
eval stolen %i.vnum%
set next %i.next_in_list%
if %pge%
%purge% %i%
end
* Don't steal mail.
if %stolen% > 1
%load% obj %stolen%
end
if !%next%
set i %actor.inventory%
else
set i %next%
end
done
eval i 0
* steal all their equipped items.
while %i% < 18
eval item %actor.eq(%i%)%
if %item%
eval stolen %item.vnum%
%purge% %item%
%load% obj %stolen%
end
eval i %i%+1
done
Code:
Name: 'More of Not Worthy', VNum: [41004], RNum: [ 3276]
Trigger Intended Assignment: Rooms
Trigger Type: Enter , Numeric Arg: 100, Arg list: None
Commands:
* Random
* Scatters the PC and their equipment all over the zone
wait 1 sec
%send% %actor% You feel you must not have been worthy when a powerful force hurls you back
through the gates.
wait 2 sec
set stunned %actor.hitp% -1
%damage% %actor% %stunned%
eval num %random.99% + 20300
%teleport% %actor% %num%
while %actor.inventory%
eval item %actor.inventory%
* checks inside containers
if %item.type% == CONTAINER
while %item.contents%
eval stolen %item.contents.vnum%
%echo% purging %item.contents.shortdesc% in container.
%purge% %item.contents%
eval num %random.99% + 2300
%at% %num% %load% obj %stolen%
done
end
eval item_to_purge %%actor.inventory(%item.vnum%)%%
eval stolen %item.vnum%
%echo% purging %item.shortdesc%.
%purge% %item_to_purge%
eval num %random.99% + 2300
%at% %num% %load% obj %stolen%
done
eval i 0
while %i% < 18
eval item %%actor.eq(%i%)%%
if %item%
eval stolen %item.vnum%
eval item_to_purge %%actor.eq(%i%)%%
%send% %actor% You drop %item.shortdesc%
%purge% %item_to_purge%
eval num %random.99% + 20300
%at% %num% %load% obj %stolen%
end
eval i %i%+1
done
%force% %actor% look
If this was helpful please
vote
or leave a
review
for TBA.
