I am not a big fan of death traps and trigedit gives some added flexibilty that many people do not know about.
A player will be in the following state at the listed hitpoints.
Dead: -11 (dead!)
Mortally Wounded: -6 (will die)
Incapacitated: -3 (will slowly die)
Stunned: 0 (will recover)
DEATHTRAPS
Rooms that will kill mortals on entry. All dropped items may be junked.
Since many people are not a fan of DT's I suggest a more painful and slow near death trap:
Example: TSTAT 3008, 12000, 6100, 6300, 41004
What this means is you can set a players hitpoints to stunned and they will have to wait for the next tick to recover. Or you can stun them, poison them and they will have to wait several ticks to heal (I did the math once, if I remember correctly poison takes away 2 hp per tick and a level 1 warrior heals 3 hp. ) Or you can Incapacitate them and make them wait a few ticks to die, evil!
Here is my favorite, I'd classify this one as advanced thanks to Mordecai's help adding container suport:
Code:
Name: 'Near Death Trap Mahatma - 6318', VNum: [ 6300], RNum: [ 916]
Trigger Intended Assignment: Mobiles
Trigger Type: Greet , Numeric Arg: 100, Arg list: None
Commands:
* By Rumble of The Builder Academy tbamud.com 9091
* Near Death Trap - Mahatma stuns actor and then takes all of their equipment.
wait 3 sec
say Here, have a quick trip to the Temple of Midgaard.
wait 2 sec
%send% %actor% Mahatma plunges a black dagger into your back and takes all your equipment.
%echoaround% %actor% Mahatma plunges a black dagger into %actor.name%'s back and takes all of %actor.hisher% equipment.
* Damage the actor to 0 hitpoints so they lay there stunned, unable to move.
* They will recover.
eval stunned %actor.hitp%
%damage% %actor% %stunned%
* steal all their inventory.
set i %actor.inventory%
while %i%
set pge 1
if %i.type% == container
if %i.contents%
set i %container.contents%
* Don't purge containers inside containers or mudmail.
if %i.type% == container || %i.vnum% <= 1
set pge 0
end
end
end
eval stolen %i.vnum%
set next %i.next_in_list%
if %pge%
%purge% %i%
end
* Don't steal mail.
if %stolen% > 1
%load% obj %stolen%
end
if !%next%
set i %actor.inventory%
else
set i %next%
end
done
eval i 0
* steal all their equipped items.
while %i% < 18
eval item %actor.eq(%i%)%
if %item%
eval stolen %item.vnum%
%purge% %item%
%load% obj %stolen%
end
eval i %i%+1
done
Or an example of a slower but still recoverable near death trap:
Code:
Name: 'Near Death Trap Spiders - 6131', VNum: [ 6100], RNum: [ 913]
Trigger Intended Assignment: Rooms
Trigger Type: Enter , Numeric Arg: 100, Arg list: None
Commands:
* Near Death Trap stuns actor, then poison will almost kill them.
wait 3 sec
eval stunned %actor.hitp%
%damage% %actor% %stunned%
wait 3 sec
dg_affect %actor% poison on 1
%send% %actor% The spiders wrap you up and leave you to die.
Trigedit can really let you get creative instead of just killing people
Feel free to leave your own opinion and ideas on death traps.
If this was helpful please
vote
or leave a
review
for TBA.
