TRIAL-VNUM-ASSIGNER ASSIGNER TRIAL-VNUM-LIMITER TBALIM JUNK-ASSIGNER LIMITER VNUM-ASSIGNER TASKS
This object was created to help new builders follow the directions under HELP TRIAL. It will limit them to a
single vnum so they can not edit other trial vnums in their zone. The assigner is loaded to every player in
the mortal greet room.
TSTAT 1306, 1365, 1366
See also: TRIAL
Code:
Name: 'Trial Vnum Assigner - 1332', VNum: [ 1306], RNum: [ 374]
Trigger Intended Assignment: Objects
Trigger Type: Command , Numeric Arg: 2, Arg list: tbalim
Commands:
* By Rumble of The Builder Academy tbamud.com 9091
* Trial vnum assigner. For STAFF only! Make sure player has nohassle off.
* Make sure name matches a player, purge mobs or use 0.name if you have
* troubles. They are given an assigner in the mortal start room.
* Usage: tbalim <player> <vnum | purge>
if !%actor.is_pc% || %actor.level% < 32
%send% %actor% Only human staff can use this limiter.
else
set victim %arg.car%
if %victim.is_pc%
if purge /= %arg.cdr% && %victim.has_item(1332)%
%send% %actor% %arg.car%'s assigner has been %arg.cdr%'d.
eval TBA_trial_vnum %victim.TBA_trial_vnum% - (2 * %victim.TBA_trial_vnum%)
remote TBA_trial_vnum %victim.id%
%purge% %victim.inventory(1332)%
else
set TBA_trial_vnum %arg.cdr%
remote TBA_trial_vnum %victim.id%
%send% %actor% %arg.car%'s trial vnum set to %arg.cdr%.
end
else
%send% %actor% Make sure they have nohassle off. Don't use it on mobs. Use 0.<name>!
return 0
end
end
Code:
Name: 'Trial Vnum Assigner - 1332', VNum: [ 1365], RNum: [ 433]
Trigger Intended Assignment: Objects
Trigger Type: Command , Numeric Arg: 2, Arg list: *
Commands:
* By Rumble of The Builder Academy tbamud.com 9091
* Player must have nohassle off! To junk assigner use tbalim purge <player>.
if %actor.varexists(TBA_trial_vnum)% && %actor.level% == 31
* We set completed trial vnums to -#. So if negative abort.
if %actor.TBA_trial_vnum% < 0
return 0
end
if (%cmd.mudcommand% == redit && ((%arg% && %arg% != %actor.TBA_trial_vnum%) || (%actor.room.vnum% != %actor.TBA_trial_vnum%)))
%send% %actor% GOTO %actor.TBA_trial_vnum% to edit your room.
elseif %cmd.mudcommand% == oedit && %arg% != %actor.TBA_trial_vnum%
%send% %actor% Use OEDIT %actor.TBA_trial_vnum% to modify your object.
elseif %cmd.mudcommand% == medit && %arg% != %actor.TBA_trial_vnum%
%send% %actor% Use MEDIT %actor.TBA_trial_vnum% to modify your mobile.
elseif (%cmd.mudcommand% == zedit && ((%arg% && %arg% != %actor.TBA_trial_vnum%) || (%actor.room.vnum% != %actor.TBA_trial_vnum%)))
%send% %actor% GOTO %actor.TBA_trial_vnum% to edit your trial vnums zone information.
elseif %cmd.mudcommand% == purge && ((%arg% && %arg% != %actor.TBA_trial_vnum%) || (%actor.room.vnum% != %actor.TBA_trial_vnum%)))
%send% %actor% GOTO %actor.TBA_trial_vnum% to purge your room.
elseif %cmd.mudcommand% == nohassle || (%cmd.mudcommand% == toggle && nohassle /= %arg.car%)
%send% %actor% You cannot enable nohassle until you finish your trial vnum.
elseif %cmd.mudcommand% == buildwalk || (%cmd.mudcommand% == toggle && buildwalk /= %arg.car%)
%send% %actor% You cannot enable buildwalk until you finish your trial vnum.
elseif %cmd.mudcommand% == sedit || %cmd.mudcommand% == trigedit || %cmd.mudcommand% == dig || %cmd.mudcommand% ==
rclone || %cmd.mudcommand% == attach || %cmd.mudcommand% == detach || %cmd.mudcommand% == vdelete
%send% %actor% Sedit, Trigedit, Dig, Rclone, Attach, Detach, and Vdelete are not required for your trial vnum.
elseif %cmd.mudcommand% == zpurge
%send% %actor% Zpurge is not required for your trial vnum. Use 'purge' or 'purge <item>.'
else
return 0
end
else
return 0
end
Code:
Name: '!DROP Assigner - 1332', VNum: [ 1366], RNum: [ 434]
Trigger Intended Assignment: Objects
Trigger Type: Drop Give Consume , Numeric Arg: 100, Arg list: None
Commands:
* By Rumble of The Builder Academy tbamud.com 9091
if %actor.level% < 32
%send% %actor% You can't get rid of %self.shortdesc%.
return 0
end
If this was helpful please
vote
or leave a
review
for TBA.
